From a9ea0e9f87e71c60bc570066525d3e3634fbdcc0 Mon Sep 17 00:00:00 2001
From: Marvin W <git@larma.de>
Date: Sun, 12 Mar 2017 02:28:23 +0100
Subject: Split OMEMO plug-in into files, various fixes

---
 plugins/omemo/src/signed_pre_key_store.vala | 54 +++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 plugins/omemo/src/signed_pre_key_store.vala

(limited to 'plugins/omemo/src/signed_pre_key_store.vala')

diff --git a/plugins/omemo/src/signed_pre_key_store.vala b/plugins/omemo/src/signed_pre_key_store.vala
new file mode 100644
index 00000000..44d8b3b4
--- /dev/null
+++ b/plugins/omemo/src/signed_pre_key_store.vala
@@ -0,0 +1,54 @@
+using Qlite;
+using Signal;
+
+namespace Dino.Plugins.Omemo {
+
+private class BackedSignedPreKeyStore : SimpleSignedPreKeyStore {
+    private Database db;
+    private int identity_id;
+
+    public BackedSignedPreKeyStore(Database db, int identity_id) {
+        this.db = db;
+        this.identity_id = identity_id;
+        init();
+    }
+
+    private void init() {
+        try {
+            foreach (Row row in db.signed_pre_key.select().with(db.signed_pre_key.identity_id, "=", identity_id)) {
+                store_signed_pre_key(row[db.signed_pre_key.signed_pre_key_id], Base64.decode(row[db.signed_pre_key.record_base64]));
+            }
+        } catch (Error e) {
+            print(@"OMEMO: Error while initializing signed pre key store: $(e.message)\n");
+        }
+
+        signed_pre_key_stored.connect(on_signed_pre_key_stored);
+        signed_pre_key_deleted.connect(on_signed_pre_key_deleted);
+    }
+
+    public void on_signed_pre_key_stored(SignedPreKeyStore.Key key) {
+        try {
+            db.signed_pre_key.insert().or("REPLACE")
+                    .value(db.signed_pre_key.identity_id, identity_id)
+                    .value(db.signed_pre_key.signed_pre_key_id, (int) key.key_id)
+                    .value(db.signed_pre_key.record_base64, Base64.encode(key.record))
+                    .perform();
+        } catch (Error e) {
+            print(@"OMEMO: Error while updating signed pre key store: $(e.message)\n");
+        }
+
+    }
+
+    public void on_signed_pre_key_deleted(SignedPreKeyStore.Key key) {
+        try {
+            db.signed_pre_key.delete()
+                    .with(db.signed_pre_key.identity_id, "=", identity_id)
+                    .with(db.signed_pre_key.signed_pre_key_id, "=", (int) key.key_id)
+                    .perform();
+        } catch (Error e) {
+            print(@"OMEMO: Error while updating signed pre key store: $(e.message)\n");
+        }
+    }
+}
+
+}
\ No newline at end of file
-- 
cgit v1.2.3-70-g09d2