Start private conversation with MUC occupant via occupant menu

3 files changed, 220 insertions, 0 deletions

diff --git a/main/src/ui/occupant_menu/list.vala b/main/src/ui/occupant_menu/list.vala
new file mode 100644
index 00000000..1e96ece4
--- /dev/null
+++ b/main/src/ui/occupant_menu/list.vala
@@ -0,0 +1,111 @@
+using Gee;
+using Gtk;
+
+using Dino.Entities;
+
+namespace Dino.Ui.OccupantMenu{
+
+[GtkTemplate (ui = "/org/dino-im/occupant_list.ui")]
+public class List : Box {
+
+    public signal void conversation_selected(Conversation? conversation);
+    private StreamInteractor stream_interactor;
+
+    [GtkChild] public ListBox list_box;
+    [GtkChild] private SearchEntry search_entry;
+
+    private Conversation? conversation;
+    private string[]? filter_values;
+    private HashMap<Jid, ListRow> rows = new HashMap<Jid, ListRow>(Jid.hash_func, Jid.equals_func);
+
+    public List(StreamInteractor stream_interactor, Conversation conversation) {
+        this.stream_interactor = stream_interactor;
+        list_box.set_header_func(header);
+        list_box.set_sort_func(sort);
+        list_box.set_filter_func(filter);
+        search_entry.search_changed.connect(search_changed);
+
+        stream_interactor.get_module(PresenceManager.IDENTITY).show_received.connect((show, jid, account) => {
+            Idle.add(() => { on_show_received(show, jid, account); return false; });
+        });
+        stream_interactor.get_module(RosterManager.IDENTITY).updated_roster_item.connect(on_updated_roster_item);
+
+        initialize_for_conversation(conversation);
+    }
+
+    public void initialize_for_conversation(Conversation conversation) {
+        this.conversation = conversation;
+        ArrayList<Jid>? occupants = stream_interactor.get_module(MucManager.IDENTITY).get_occupants(conversation.counterpart, conversation.account);
+        if (occupants != null) {
+            foreach (Jid occupant in occupants) {
+                add_occupant(occupant);
+            }
+        }
+    }
+
+    private void refilter() {
+        string[]? values = null;
+        string str = search_entry.get_text ();
+        if (str != "") values = str.split(" ");
+        if (filter_values == values) return;
+        filter_values = values;
+        list_box.invalidate_filter();
+    }
+
+    private void search_changed(Editable editable) {
+        refilter();
+    }
+
+    public void add_occupant(Jid jid) {
+        rows[jid] = new ListRow(stream_interactor, conversation.account, jid);
+        list_box.add(rows[jid]);
+        list_box.invalidate_filter();
+        list_box.invalidate_sort();
+    }
+
+    public void remove_occupant(Jid jid) {
+        list_box.remove(rows[jid]);
+        rows.unset(jid);
+    }
+
+    private void on_updated_roster_item(Account account, Jid jid, Xmpp.Roster.Item roster_item) {
+
+    }
+
+    private void on_show_received(Show show, Jid jid, Account account) {
+        if (conversation != null && conversation.counterpart.equals_bare(jid)) {
+            if (show.as == Show.OFFLINE && rows.has_key(jid)) {
+                remove_occupant(jid);
+            } else if (show.as != Show.OFFLINE && !rows.has_key(jid)) {
+                add_occupant(jid);
+            }
+        }
+    }
+
+    private void header(ListBoxRow row, ListBoxRow? before_row) {
+        if (row.get_header() == null && before_row != null) {
+            row.set_header(new Separator(Orientation.HORIZONTAL));
+        }
+    }
+
+    private bool filter(ListBoxRow r) {
+        if (r.get_type().is_a(typeof(ListRow))) {
+            ListRow row = r as ListRow;
+            foreach (string filter in filter_values) {
+                return row.name_label.label.down().contains(filter.down());
+            }
+        }
+        return true;
+    }
+
+    private int sort(ListBoxRow row1, ListBoxRow row2) {
+        if (row1.get_type().is_a(typeof(ListRow)) && row2.get_type().is_a(typeof(ListRow))) {
+            ListRow c1 = row1 as ListRow;
+            ListRow c2 = row2 as ListRow;
+            return c1.name_label.label.collate(c2.name_label.label);
+        }
+        return 0;
+    }
+}
+
+}
\ No newline at end of file
diff --git a/main/src/ui/occupant_menu/list_row.vala b/main/src/ui/occupant_menu/list_row.vala
new file mode 100644
index 00000000..b8b95758
--- /dev/null
+++ b/main/src/ui/occupant_menu/list_row.vala
@@ -0,0 +1,30 @@
+using Gtk;
+
+using Dino.Entities;
+using Xmpp;
+
+namespace Dino.Ui.OccupantMenu {
+
+[GtkTemplate (ui = "/org/dino-im/occupant_list_item.ui")]
+public class ListRow : ListBoxRow {
+
+    [GtkChild] private Image image;
+    [GtkChild] public Label name_label;
+
+    public Account account;
+    public Jid jid;
+
+    public ListRow(StreamInteractor stream_interactor, Account account, Jid jid) {
+        this.account = account;
+        this.jid = jid;
+
+        name_label.label = Util.get_display_name(stream_interactor, jid, account);
+        Util.image_set_from_scaled_pixbuf(image, (new AvatarGenerator(30, 30, image.scale_factor)).draw_jid(stream_interactor, jid, account));
+    }
+
+    public void on_presence_received(Presence.Stanza presence) {
+
+    }
+}
+
+}
\ No newline at end of file
diff --git a/main/src/ui/occupant_menu/view.vala b/main/src/ui/occupant_menu/view.vala
new file mode 100644
index 00000000..b7fe15ba
--- /dev/null
+++ b/main/src/ui/occupant_menu/view.vala
@@ -0,0 +1,79 @@
+using Gtk;
+
+using Dino.Entities;
+
+namespace Dino.Ui.OccupantMenu {
+public class View : Popover {
+
+    private StreamInteractor stream_interactor;
+    private Conversation conversation;
+
+    private Stack stack = new Stack() { vhomogeneous=false, visible=true };
+    private List list;
+    private Label header_label = new Label("") { xalign=0.5f, hexpand=true, visible=true };
+
+    public View(StreamInteractor stream_interactor, Conversation conversation) {
+        this.stream_interactor = stream_interactor;
+        this.conversation = conversation;
+
+        list = new List(stream_interactor, conversation) { visible=true };
+        stack.add_named(list, "list");
+        setup_menu();
+        add(stack);
+        stack.visible_child_name = "list";
+
+        list.list_box.row_activated.connect((row) => {
+            ListRow list_row = row as ListRow;
+            header_label.label = list_row.name_label.label;
+            show_menu();
+        });
+
+        hide.connect(reset);
+    }
+
+    public void reset() {
+        stack.transition_type = StackTransitionType.NONE;
+        stack.visible_child_name = "list";
+        list.list_box.unselect_all();
+    }
+
+    private void setup_menu() {
+        Box header_box = new Box(Orientation.HORIZONTAL, 5) { visible=true };
+        header_box.add(new Image.from_icon_name("pan-start-symbolic", IconSize.SMALL_TOOLBAR) { visible=true });
+        header_box.add(header_label);
+
+        Button header_button = new Button() { relief=ReliefStyle.NONE, visible=true };
+        header_button.add(header_box);
+
+        ModelButton private_button = new ModelButton()  { active=true, text="Start private conversation", visible=true };
+
+        Box outer_box = new Box(Orientation.VERTICAL, 5) { margin=10, visible=true };
+        outer_box.add(header_button);
+        outer_box.add(private_button);
+        stack.add_named(outer_box, "menu");
+
+        header_button.clicked.connect(show_list);
+        private_button.clicked.connect(private_conversation_button_clicked);
+    }
+
+    private void show_list() {
+        list.list_box.unselect_all();
+        stack.transition_type = StackTransitionType.SLIDE_RIGHT;
+        stack.visible_child_name = "list";
+    }
+
+    private void show_menu() {
+        stack.transition_type = StackTransitionType.SLIDE_LEFT;
+        stack.visible_child_name = "menu";
+    }
+
+    private void private_conversation_button_clicked() {
+        ListRow? list_row = list.list_box.get_selected_row() as ListRow;
+        if (list_row == null) return;
+
+        Conversation conversation = stream_interactor.get_module(ConversationManager.IDENTITY).create_conversation(list_row.jid, list_row.account, Conversation.Type.GROUPCHAT_PM);
+        stream_interactor.get_module(ConversationManager.IDENTITY).start_conversation(conversation, true);
+    }
+}
+
+}
\ No newline at end of file