refactor conversation item management (accumulate them in libdino)

12 files changed, 347 insertions, 527 deletions

diff --git a/main/src/ui/conversation_summary/chat_state_populator.vala b/main/src/ui/conversation_summary/chat_state_populator.vala
index 1ea52a6d..d07ab743 100644
--- a/main/src/ui/conversation_summary/chat_state_populator.vala
+++ b/main/src/ui/conversation_summary/chat_state_populator.vala
@@ -6,7 +6,7 @@ using Xmpp;
 
 namespace Dino.Ui.ConversationSummary {
 
-class ChatStatePopulator : Plugins.ConversationItemPopulator, Object {
+class ChatStatePopulator : Plugins.ConversationItemPopulator, Plugins.ConversationAdditionPopulator, Object {
 
     public string id { get { return "chat_state"; } }
 
@@ -43,8 +43,6 @@ class ChatStatePopulator : Plugins.ConversationItemPopulator, Object {
 
     public void populate_timespan(Conversation conversation, DateTime from, DateTime to) { }
 
-    public void populate_between_widgets(Conversation conversation, DateTime from, DateTime to) { }
-
     private void update_chat_state(Account account, Jid jid) {
         HashMap<Jid, string>? states = stream_interactor.get_module(CounterpartInteractionManager.IDENTITY).get_chat_states(current_conversation);
 
diff --git a/main/src/ui/conversation_summary/content_item_widget_factory.vala b/main/src/ui/conversation_summary/content_item_widget_factory.vala
new file mode 100644
index 00000000..8a2bf136
--- /dev/null
+++ b/main/src/ui/conversation_summary/content_item_widget_factory.vala
@@ -0,0 +1,224 @@
+using Gee;
+using Gdk;
+using Gtk;
+
+using Dino.Entities;
+
+namespace Dino.Ui.ConversationSummary {
+
+public class ContentItemWidgetFactory : Object {
+
+    private StreamInteractor stream_interactor;
+    private HashMap<string, WidgetGenerator> generators = new HashMap<string, WidgetGenerator>();
+
+    public ContentItemWidgetFactory(StreamInteractor stream_interactor) {
+        this.stream_interactor = stream_interactor;
+
+        generators[MessageItem.TYPE] = new MessageItemWidgetGenerator(stream_interactor);
+        generators[FileItem.TYPE] = new FileItemWidgetGenerator(stream_interactor);
+    }
+
+    public Widget? get_widget(ContentItem item) {
+        WidgetGenerator? generator = generators[item.type_];
+        if (generator != null) {
+            return (Widget?) generator.get_widget(item);
+        }
+        return null;
+    }
+
+    public void register_widget_generator(WidgetGenerator generator) {
+        generators[generator.handles_type] = generator;
+    }
+}
+
+public interface WidgetGenerator : Object {
+    public abstract string handles_type { get; set; }
+    public abstract Object get_widget(ContentItem item);
+}
+
+public class MessageItemWidgetGenerator : WidgetGenerator, Object {
+
+    public string handles_type { get; set; default=FileItem.TYPE; }
+
+    private StreamInteractor stream_interactor;
+
+    public MessageItemWidgetGenerator(StreamInteractor stream_interactor) {
+        this.stream_interactor = stream_interactor;
+    }
+
+    public Object get_widget(ContentItem item) {
+        MessageItem message_item = item as MessageItem;
+        Conversation conversation = message_item.conversation;
+        Message message = message_item.message;
+
+        MessageTextView text_view = new MessageTextView() { vexpand=true, visible = true };
+
+        if (message_item.message.body.has_prefix("/me")) {
+            text_view.add_text(message.body.substring(3));
+        } else {
+            text_view.add_text(message.body);
+        }
+        if (conversation.type_ == Conversation.Type.GROUPCHAT)  {
+            text_view.highlight_word(conversation.nickname);
+        }
+        if (message_item.message.body.has_prefix("/me")) {
+            string display_name = Util.get_message_display_name(stream_interactor, message, conversation.account);
+            string color = Util.get_name_hex_color(stream_interactor, conversation.account, conversation.counterpart, Util.is_dark_theme(text_view));
+            TextTag nick_tag = text_view.buffer.create_tag(null, foreground: @"#$color");
+            TextIter iter;
+            text_view.buffer.get_start_iter(out iter);
+            text_view.buffer.insert_with_tags(ref iter, display_name, display_name.length, nick_tag);
+
+            text_view.style_updated.connect(() => update_style(stream_interactor, message, conversation, nick_tag, text_view));
+            text_view.realize.connect(() => update_style(stream_interactor, message, conversation, nick_tag, text_view));
+        }
+        return text_view;
+    }
+
+    public static void update_style(StreamInteractor stream_interactor, Message message, Conversation conversation, TextTag nick_tag, TextView text_view) {
+        string color = Util.get_name_hex_color(stream_interactor, conversation.account, message.real_jid ?? message.from, Util.is_dark_theme(text_view));
+        nick_tag.foreground = "#" + color;
+    }
+}
+
+public class FileItemWidgetGenerator : WidgetGenerator, Object {
+
+    public StreamInteractor stream_interactor;
+    public string handles_type { get; set; default=FileItem.TYPE; }
+
+    private const int MAX_HEIGHT = 300;
+    private const int MAX_WIDTH = 600;
+
+    public FileItemWidgetGenerator(StreamInteractor stream_interactor) {
+        this.stream_interactor = stream_interactor;
+    }
+
+    public Object get_widget(ContentItem item) {
+        FileItem file_item = item as FileItem;
+        FileTransfer transfer = file_item.file_transfer;
+        if (transfer.mime_type != null && transfer.mime_type.has_prefix("image")) {
+            return getImageWidget(transfer);
+        } else {
+            return getDefaultWidget(transfer);
+        }
+    }
+
+    private Widget getImageWidget(FileTransfer file_transfer) {
+        Image image = new Image() { halign=Align.START, visible = true };
+        Gdk.Pixbuf pixbuf;
+        try {
+            pixbuf = new Gdk.Pixbuf.from_file(file_transfer.get_file().get_path());
+        } catch (Error error) {
+            return null;
+        }
+
+        int max_scaled_height = MAX_HEIGHT * image.scale_factor;
+        if (pixbuf.height > max_scaled_height) {
+            pixbuf = pixbuf.scale_simple((int) ((double) max_scaled_height / pixbuf.height * pixbuf.width), max_scaled_height, Gdk.InterpType.BILINEAR);
+        }
+        int max_scaled_width = MAX_WIDTH * image.scale_factor;
+        if (pixbuf.width > max_scaled_width) {
+            pixbuf = pixbuf.scale_simple(max_scaled_width, (int) ((double) max_scaled_width / pixbuf.width * pixbuf.height), Gdk.InterpType.BILINEAR);
+        }
+        pixbuf = crop_corners(pixbuf, 3 * image.get_scale_factor());
+        Util.image_set_from_scaled_pixbuf(image, pixbuf);
+        Util.force_css(image, "* { box-shadow: 0px 0px 2px 0px rgba(0,0,0,0.1); margin: 2px; border-radius: 3px; }");
+
+        Builder builder = new Builder.from_resource("/im/dino/Dino/conversation_summary/image_toolbar.ui");
+        Widget toolbar = builder.get_object("main") as Widget;
+        Util.force_background(toolbar, "rgba(0, 0, 0, 0.5)");
+        Util.force_css(toolbar, "* { padding: 3px; border-radius: 3px; }");
+
+        Label url_label = builder.get_object("url_label") as Label;
+        Util.force_color(url_label, "#eee");
+
+        if (file_transfer.file_name != null && file_transfer.file_name != "") {
+            string caption = file_transfer.file_name;
+            url_label.label = caption;
+        } else {
+            url_label.visible = false;
+        }
+
+        Image open_image = builder.get_object("open_image") as Image;
+        Util.force_css(open_image, "*:not(:hover) { color: #eee; }");
+        Button open_button = builder.get_object("open_button") as Button;
+        Util.force_css(open_button, "*:hover { background-color: rgba(255,255,255,0.3); border-color: transparent; }");
+        open_button.clicked.connect(() => {
+            try{
+                AppInfo.launch_default_for_uri(file_transfer.get_file().get_uri(), null);
+            } catch (Error err) {
+                print("Tried to open file://" + file_transfer.get_file().get_path() + " " + err.message + "\n");
+            }
+        });
+
+        Revealer toolbar_revealer = new Revealer() { transition_type=RevealerTransitionType.CROSSFADE, transition_duration=400, visible=true };
+        toolbar_revealer.add(toolbar);
+
+        Grid grid = new Grid() { visible=true };
+        grid.attach(toolbar_revealer, 0, 0, 1, 1);
+        grid.attach(image, 0, 0, 1, 1);
+
+        EventBox event_box = new EventBox() { halign=Align.START, visible=true };
+        event_box.add(grid);
+        event_box.enter_notify_event.connect(() => { toolbar_revealer.reveal_child = true; return false; });
+        event_box.leave_notify_event.connect(() => { toolbar_revealer.reveal_child = false; return false; });
+
+        return event_box;
+    }
+
+    private static Gdk.Pixbuf crop_corners(Gdk.Pixbuf pixbuf, double radius = 3) {
+        Cairo.Context ctx = new Cairo.Context(new Cairo.ImageSurface(Cairo.Format.ARGB32, pixbuf.width, pixbuf.height));
+        Gdk.cairo_set_source_pixbuf(ctx, pixbuf, 0, 0);
+        double degrees = Math.PI / 180.0;
+        ctx.new_sub_path();
+        ctx.arc(pixbuf.width - radius, radius, radius, -90 * degrees, 0 * degrees);
+        ctx.arc(pixbuf.width - radius, pixbuf.height - radius, radius, 0 * degrees, 90 * degrees);
+        ctx.arc(radius, pixbuf.height - radius, radius, 90 * degrees, 180 * degrees);
+        ctx.arc(radius, radius, radius, 180 * degrees, 270 * degrees);
+        ctx.close_path();
+        ctx.clip();
+        ctx.paint();
+        return Gdk.pixbuf_get_from_surface(ctx.get_target(), 0, 0, pixbuf.width, pixbuf.height);
+    }
+
+    private Widget getDefaultWidget(FileTransfer file_transfer) {
+        Box main_box = new Box(Orientation.HORIZONTAL, 4) { halign=Align.START, visible=true };
+        string? icon_name = ContentType.get_generic_icon_name(file_transfer.mime_type);
+        Image content_type_image = new Image.from_icon_name(icon_name, IconSize.DND) { visible=true };
+        main_box.add(content_type_image);
+
+        Box right_box = new Box(Orientation.VERTICAL, 0) { visible=true };
+        Label name_label = new Label(file_transfer.file_name) { xalign=0, yalign=0, visible=true};
+        right_box.add(name_label);
+        Label mime_label = new Label("<span size='small'>" + _("File") + ": " + file_transfer.mime_type + "</span>") { use_markup=true, xalign=0, yalign=1, visible=true};
+        mime_label.get_style_context().add_class("dim-label");
+        right_box.add(mime_label);
+        main_box.add(right_box);
+
+        EventBox event_box = new EventBox() { halign=Align.START, visible=true };
+        event_box.add(main_box);
+
+        event_box.enter_notify_event.connect((event) => {
+            event.get_window().set_cursor(new Cursor.for_display(Gdk.Display.get_default(), CursorType.HAND2));
+            return false;
+        });
+        event_box.leave_notify_event.connect((event) => {
+            event.get_window().set_cursor(new Cursor.for_display(Gdk.Display.get_default(), CursorType.XTERM));
+            return false;
+        });
+        event_box.button_release_event.connect((event_button) => {
+            if (event_button.button == 1) {
+                try{
+                    AppInfo.launch_default_for_uri(file_transfer.get_file().get_uri(), null);
+                } catch (Error err) {
+                    print("Tried to open " + file_transfer.get_file().get_path());
+                }
+            }
+            return false;
+        });
+
+        return event_box;
+    }
+}
+
+}
diff --git a/main/src/ui/conversation_summary/content_populator.vala b/main/src/ui/conversation_summary/content_populator.vala
new file mode 100644
index 00000000..9fb83419
--- /dev/null
+++ b/main/src/ui/conversation_summary/content_populator.vala
@@ -0,0 +1,99 @@
+using Gee;
+using Gtk;
+
+using Xmpp;
+using Dino.Entities;
+
+namespace Dino.Ui.ConversationSummary {
+
+public class ContentProvider : ContentItemCollection, Object {
+
+    private StreamInteractor stream_interactor;
+    private ContentItemWidgetFactory widget_factory;
+    private Conversation? current_conversation;
+    private Plugins.ConversationItemCollection? item_collection;
+
+    public ContentProvider(StreamInteractor stream_interactor) {
+        this.stream_interactor = stream_interactor;
+        this.widget_factory =  new ContentItemWidgetFactory(stream_interactor);
+    }
+
+    public void init(Plugins.ConversationItemCollection item_collection, Conversation conversation, Plugins.WidgetType type) {
+        current_conversation = conversation;
+        this.item_collection = item_collection;
+        stream_interactor.get_module(ContentItemAccumulator.IDENTITY).init(conversation, this);
+    }
+
+    public void close(Conversation conversation) { }
+
+    public void insert_item(ContentItem item) {
+        item_collection.insert_item(new ContentMetaItem(item, widget_factory));
+    }
+
+    public void remove_item(ContentItem item) { }
+
+
+    public Gee.List<ContentMetaItem> populate_latest(Conversation conversation, int n) {
+        Gee.List<ContentItem> items = stream_interactor.get_module(ContentItemAccumulator.IDENTITY).populate_latest(this, conversation, n);
+        Gee.List<ContentMetaItem> ret = new ArrayList<ContentMetaItem>();
+        foreach (ContentItem item in items) {
+            ret.add(new ContentMetaItem(item, widget_factory));
+        }
+        return ret;
+    }
+
+    public Gee.List<ContentMetaItem> populate_before(Conversation conversation, Plugins.MetaConversationItem before_item, int n) {
+        Gee.List<ContentMetaItem> ret = new ArrayList<ContentMetaItem>();
+        ContentMetaItem? content_meta_item = before_item as ContentMetaItem;
+        if (content_meta_item != null) {
+            Gee.List<ContentItem> items = stream_interactor.get_module(ContentItemAccumulator.IDENTITY).populate_before(this, conversation, content_meta_item.content_item, n);
+            foreach (ContentItem item in items) {
+                ret.add(new ContentMetaItem(item, widget_factory));
+            }
+        }
+        return ret;
+    }
+}
+
+public class ContentMetaItem : Plugins.MetaConversationItem {
+    public override Jid? jid { get; set; }
+    public override DateTime? sort_time { get; set; }
+    public override DateTime? display_time { get; set; }
+    public override Encryption? encryption { get; set; }
+
+    public ContentItem content_item;
+    private ContentItemWidgetFactory widget_factory;
+
+    public ContentMetaItem(ContentItem content_item, ContentItemWidgetFactory widget_factory) {
+        this.jid = content_item.jid;
+        this.sort_time = content_item.sort_time;
+        this.seccondary_sort_indicator = content_item.seccondary_sort_indicator;
+        this.display_time = content_item.display_time;
+        this.encryption = content_item.encryption;
+        this.mark = content_item.mark;
+
+        WeakRef weak_item = WeakRef(content_item);
+        content_item.notify["mark"].connect(() => {
+            ContentItem? ci = weak_item.get() as ContentItem;
+            if (ci == null) return;
+            this.mark = ci.mark;
+        });
+
+        this.can_merge = true;
+        this.requires_avatar = true;
+        this.requires_header = true;
+
+        this.content_item = content_item;
+        this.widget_factory = widget_factory;
+    }
+
+    public override bool can_merge { get; set; default=true; }
+    public override bool requires_avatar { get; set; default=true; }
+    public override bool requires_header { get; set; default=true; }
+
+    public override Object? get_widget(Plugins.WidgetType type) {
+        return widget_factory.get_widget(content_item);
+    }
+}
+
+}
diff --git a/main/src/ui/conversation_summary/conversation_view.vala b/main/src/ui/conversation_summary/conversation_view.vala
index fac53b7d..bb696572 100644
--- a/main/src/ui/conversation_summary/conversation_view.vala
+++ b/main/src/ui/conversation_summary/conversation_view.vala
@@ -19,11 +19,10 @@ public class ConversationView : Box, Plugins.ConversationItemCollection {
 
     private StreamInteractor stream_interactor;
     private Gee.TreeSet<Plugins.MetaConversationItem> meta_items = new TreeSet<Plugins.MetaConversationItem>(sort_meta_items);
-    private Gee.Map<Plugins.MetaConversationItem, Gee.List<Plugins.MetaConversationItem>> meta_after_items = new Gee.HashMap<Plugins.MetaConversationItem, Gee.List<Plugins.MetaConversationItem>>();
     private Gee.HashMap<Plugins.MetaConversationItem, ConversationItemSkeleton> item_item_skeletons = new Gee.HashMap<Plugins.MetaConversationItem, ConversationItemSkeleton>();
     private Gee.HashMap<Plugins.MetaConversationItem, Widget> widgets = new Gee.HashMap<Plugins.MetaConversationItem, Widget>();
     private Gee.List<ConversationItemSkeleton> item_skeletons = new Gee.ArrayList<ConversationItemSkeleton>();
-    private MessagePopulator message_item_populator;
+    private ContentProvider content_populator;
     private SubscriptionNotitication subscription_notification;
 
     private double? was_value;
@@ -39,16 +38,15 @@ public class ConversationView : Box, Plugins.ConversationItemCollection {
         scrolled.vadjustment.notify["upper"].connect_after(on_upper_notify);
         scrolled.vadjustment.notify["value"].connect(on_value_notify);
 
-        message_item_populator = new MessagePopulator(stream_interactor);
+        content_populator = new ContentProvider(stream_interactor);
         subscription_notification = new SubscriptionNotitication(stream_interactor);
 
         insert_item.connect(on_insert_item);
         remove_item.connect(on_remove_item);
 
         Application app = GLib.Application.get_default() as Application;
-        app.plugin_registry.register_conversation_item_populator(new ChatStatePopulator(stream_interactor));
-        app.plugin_registry.register_conversation_item_populator(new FilePopulator(stream_interactor));
-        app.plugin_registry.register_conversation_item_populator(new DateSeparatorPopulator(stream_interactor));
+        app.plugin_registry.register_conversation_addition_populator(new ChatStatePopulator(stream_interactor));
+        app.plugin_registry.register_conversation_addition_populator(new DateSeparatorPopulator(stream_interactor));
 
         Timeout.add_seconds(60, () => {
             foreach (ConversationItemSkeleton item_skeleton in item_skeletons) {
@@ -78,7 +76,7 @@ public class ConversationView : Box, Plugins.ConversationItemCollection {
     private void initialize_for_conversation_(Conversation? conversation) {
         Dino.Application app = Dino.Application.get_default();
         if (this.conversation != null) {
-            foreach (Plugins.ConversationItemPopulator populator in app.plugin_registry.conversation_item_populators) {
+            foreach (Plugins.ConversationItemPopulator populator in app.plugin_registry.conversation_addition_populators) {
                 populator.close(conversation);
             }
         }
@@ -90,11 +88,14 @@ public class ConversationView : Box, Plugins.ConversationItemCollection {
         animate = false;
         Timeout.add(20, () => { animate = true; return false; });
 
-        foreach (Plugins.ConversationItemPopulator populator in app.plugin_registry.conversation_item_populators) {
+        foreach (Plugins.ConversationItemPopulator populator in app.plugin_registry.conversation_addition_populators) {
             populator.init(conversation, this, Plugins.WidgetType.GTK);
         }
-        message_item_populator.init(conversation, this);
-        message_item_populator.populate_latest(conversation, 40);
+        content_populator.init(this, conversation, Plugins.WidgetType.GTK);
+        Gee.List<ContentMetaItem> items = content_populator.populate_latest(conversation, 40);
+        foreach (ContentMetaItem item in items) {
+            on_insert_item(item);
+        }
         Idle.add(() => { on_value_notify(); return false; });
 
         subscription_notification.init(conversation, this);
@@ -110,7 +111,7 @@ public class ConversationView : Box, Plugins.ConversationItemCollection {
         }
     }
 
-    public void on_remove_item(Plugins.MetaConversationItem item) {
+    private void on_remove_item(Plugins.MetaConversationItem item) {
         lock (meta_items) {
             ConversationItemSkeleton? skeleton = item_item_skeletons[item];
             if (skeleton.items.size > 1) {
@@ -202,11 +203,11 @@ public class ConversationView : Box, Plugins.ConversationItemCollection {
         if (index == 0) {
             Dino.Application app = Dino.Application.get_default();
             if (item_skeletons.size == 1) {
-                foreach (Plugins.ConversationItemPopulator populator in app.plugin_registry.conversation_item_populators) {
+                foreach (Plugins.ConversationAdditionPopulator populator in app.plugin_registry.conversation_addition_populators) {
                     populator.populate_timespan(conversation, item.sort_time, new DateTime.now_utc());
                 }
             } else {
-                foreach (Plugins.ConversationItemPopulator populator in app.plugin_registry.conversation_item_populators) {
+                foreach (Plugins.ConversationAdditionPopulator populator in app.plugin_registry.conversation_addition_populators) {
                     populator.populate_timespan(conversation, item.sort_time, meta_items.higher(item).sort_time);
                 }
             }
@@ -253,7 +254,12 @@ public class ConversationView : Box, Plugins.ConversationItemCollection {
     private void load_earlier_messages() {
         was_value = scrolled.vadjustment.value;
         if (!reloading_mutex.trylock()) return;
-        if (meta_items.size > 0) message_item_populator.populate_before(conversation, meta_items.first(), 20);
+        if (meta_items.size > 0) {
+            Gee.List<ContentMetaItem> items = content_populator.populate_before(conversation, meta_items.first(), 20);
+            foreach (ContentMetaItem item in items) {
+                on_insert_item(item);
+            }
+        }
     }
 
     private static int sort_meta_items(Plugins.MetaConversationItem a, Plugins.MetaConversationItem b) {
@@ -276,7 +282,6 @@ public class ConversationView : Box, Plugins.ConversationItemCollection {
 
     private void clear() {
         meta_items.clear();
-        meta_after_items.clear();
         item_skeletons.clear();
         item_item_skeletons.clear();
         widgets.clear();
diff --git a/main/src/ui/conversation_summary/date_separator_populator.vala b/main/src/ui/conversation_summary/date_separator_populator.vala
index 34005ab6..6a1ba782 100644
--- a/main/src/ui/conversation_summary/date_separator_populator.vala
+++ b/main/src/ui/conversation_summary/date_separator_populator.vala
@@ -6,7 +6,7 @@ using Xmpp;
 
 namespace Dino.Ui.ConversationSummary {
 
-class DateSeparatorPopulator : Plugins.ConversationItemPopulator, Object {
+class DateSeparatorPopulator : Plugins.ConversationItemPopulator, Plugins.ConversationAdditionPopulator, Object {
 
     public string id { get { return "date_separator"; } }
 
@@ -35,8 +35,6 @@ class DateSeparatorPopulator : Plugins.ConversationItemPopulator, Object {
 
     public void populate_timespan(Conversation conversation, DateTime after, DateTime before) { }
 
-    public void populate_between_widgets(Conversation conversation, DateTime from, DateTime to) { }
-
     private void on_insert_item(Plugins.MetaConversationItem item) {
         if (item.display_time == null) return;
 
diff --git a/main/src/ui/conversation_summary/default_file_display.vala b/main/src/ui/conversation_summary/default_file_display.vala
deleted file mode 100644
index 1547440b..00000000
--- a/main/src/ui/conversation_summary/default_file_display.vala
+++ /dev/null
@@ -1,95 +0,0 @@
-using Gdk;
-using Gtk;
-
-using Dino.Entities;
-using Xmpp;
-
-namespace Dino.Ui.ConversationSummary {
-
-public class DefaultFileDisplay : Plugins.MetaConversationItem {
-    public override Jid? jid { get; set; }
-    public override DateTime? sort_time { get; set; }
-    public override DateTime? display_time { get; set; }
-    public override Encryption? encryption { get; set; }
-    public override Entities.Message.Marked? mark { get; set; }
-
-    public override bool can_merge { get; set; default=true; }
-    public override bool requires_avatar { get; set; default=true; }
-    public override bool requires_header { get; set; default=true; }
-
-    private const int MAX_HEIGHT = 300;
-    private const int MAX_WIDTH = 600;
-
-    private StreamInteractor stream_interactor;
-    private FileTransfer file_transfer;
-
-    public DefaultFileDisplay(StreamInteractor stream_interactor, FileTransfer file_transfer) {
-        this.stream_interactor = stream_interactor;
-        this.file_transfer = file_transfer;
-
-        this.jid = file_transfer.direction == FileTransfer.DIRECTION_SENT ? file_transfer.account.bare_jid.with_resource(file_transfer.account.resourcepart) : file_transfer.counterpart;
-        this.sort_time = file_transfer.time;
-        this.seccondary_sort_indicator = file_transfer.id + 0.2903;
-        this.display_time = file_transfer.time;
-        this.encryption = file_transfer.encryption;
-        this.mark = file_to_message_state(file_transfer.state);
-        file_transfer.notify["state"].connect_after(() => {
-            this.mark = file_to_message_state(file_transfer.state);
-        });
-    }
-
-    public override Object? get_widget(Plugins.WidgetType widget_type) {
-        Box main_box = new Box(Orientation.HORIZONTAL, 4) { halign=Align.START, visible=true };
-        string? icon_name = ContentType.get_generic_icon_name(file_transfer.mime_type);
-        Image content_type_image = new Image.from_icon_name(icon_name, IconSize.DND) { visible=true };
-        main_box.add(content_type_image);
-
-        Box right_box = new Box(Orientation.VERTICAL, 0) { visible=true };
-        Label name_label = new Label(file_transfer.file_name) { xalign=0, yalign=0, visible=true};
-        right_box.add(name_label);
-        Label mime_label = new Label("<span size='small'>" + _("File") + ": " + file_transfer.mime_type + "</span>") { use_markup=true, xalign=0, yalign=1, visible=true};
-        mime_label.get_style_context().add_class("dim-label");
-        right_box.add(mime_label);
-        main_box.add(right_box);
-
-        EventBox event_box = new EventBox() { halign=Align.START, visible=true };
-        event_box.add(main_box);
-
-        event_box.enter_notify_event.connect((event) => {
-            event.get_window().set_cursor(new Cursor.for_display(Gdk.Display.get_default(), CursorType.HAND2));
-            return false;
-        });
-        event_box.leave_notify_event.connect((event) => {
-            event.get_window().set_cursor(new Cursor.for_display(Gdk.Display.get_default(), CursorType.XTERM));
-            return false;
-        });
-        event_box.button_release_event.connect((event_button) => {
-            if (event_button.button == 1) {
-                try{
-                    AppInfo.launch_default_for_uri(file_transfer.get_file().get_uri(), null);
-                } catch (Error err) {
-                    print("Tried to open " + file_transfer.get_file().get_path());
-                }
-            }
-            return false;
-        });
-
-        return event_box;
-    }
-
-    private Entities.Message.Marked file_to_message_state(FileTransfer.State state) {
-        switch (state) {
-            case FileTransfer.State.IN_PROCESS:
-                return Entities.Message.Marked.UNSENT;
-            case FileTransfer.State.COMPLETE:
-                return Entities.Message.Marked.NONE;
-            case FileTransfer.State.NOT_STARTED:
-                return Entities.Message.Marked.UNSENT;
-            case FileTransfer.State.FAILED:
-                return Entities.Message.Marked.WONTSEND;
-        }
-        assert_not_reached();
-    }
-}
-
-}
diff --git a/main/src/ui/conversation_summary/default_message_display.vala b/main/src/ui/conversation_summary/default_message_display.vala
deleted file mode 100644
index 519e5107..00000000
--- a/main/src/ui/conversation_summary/default_message_display.vala
+++ /dev/null
@@ -1,58 +0,0 @@
-using Dino.Entities;
-using Xmpp;
-
-namespace Dino.Ui.ConversationSummary {
-
-public class DefaultMessageDisplay : Plugins.MessageDisplayProvider, Object {
-    public string id { get; set; default="default"; }
-    public double priority { get; set; default=0; }
-
-    public StreamInteractor stream_interactor;
-
-    public DefaultMessageDisplay(StreamInteractor stream_interactor) {
-        this.stream_interactor = stream_interactor;
-    }
-
-    public bool can_display(Entities.Message? message) { return true; }
-
-    public Plugins.MetaConversationItem? get_item(Entities.Message message, Conversation conversation) {
-        return new MetaMessageItem(stream_interactor, message, conversation);
-    }
-}
-
-public class MetaMessageItem : Plugins.MetaConversationItem {
-    public override Jid? jid { get; set; }
-    public override DateTime? sort_time { get; set; }
-    public override DateTime? display_time { get; set; }
-    public override Encryption? encryption { get; set; }
-
-    private StreamInteractor stream_interactor;
-    private Conversation conversation;
-    private Message message;
-
-    public MetaMessageItem(StreamInteractor stream_interactor, Message message, Conversation conversation) {
-        this.stream_interactor = stream_interactor;
-        this.conversation = conversation;
-        this.message = message;
-        this.jid = message.from;
-        this.sort_time = message.local_time;
-        this.seccondary_sort_indicator = message.id + 0.2085;
-        this.display_time = message.time;
-        this.encryption = message.encryption;
-    }
-
-    public override bool can_merge { get; set; default=true; }
-    public override bool requires_avatar { get; set; default=true; }
-    public override bool requires_header { get; set; default=true; }
-
-    public override Object? get_widget(Plugins.WidgetType widget_type) {
-        MessageTextView text_view = new MessageTextView() { visible = true };
-        text_view.add_text(message.body);
-        if (conversation.type_ == Conversation.Type.GROUPCHAT)  {
-            text_view.highlight_word(conversation.nickname);
-        }
-        return text_view;
-    }
-}
-
-}
diff --git a/main/src/ui/conversation_summary/file_populator.vala b/main/src/ui/conversation_summary/file_populator.vala
deleted file mode 100644
index af7bc992..00000000
--- a/main/src/ui/conversation_summary/file_populator.vala
+++ /dev/null
@@ -1,54 +0,0 @@
-using Gee;
-using Gtk;
-
-using Dino.Entities;
-using Xmpp;
-
-namespace Dino.Ui.ConversationSummary {
-
-class FilePopulator : Plugins.ConversationItemPopulator, Object {
-
-    public string id { get { return "file"; } }
-
-    private StreamInteractor? stream_interactor;
-    private Conversation? current_conversation;
-    private Plugins.ConversationItemCollection? item_collection;
-
-    public FilePopulator(StreamInteractor stream_interactor) {
-        this.stream_interactor = stream_interactor;
-
-        stream_interactor.get_module(FileManager.IDENTITY).received_file.connect((file_transfer) => {
-            if (current_conversation != null && current_conversation.account.equals(file_transfer.account) && current_conversation.counterpart.equals_bare(file_transfer.counterpart)) {
-                insert_file(file_transfer);
-            }
-        });
-    }
-
-    public void init(Conversation conversation, Plugins.ConversationItemCollection item_collection, Plugins.WidgetType type) {
-        current_conversation = conversation;
-        this.item_collection = item_collection;
-    }
-
-    public void close(Conversation conversation) { }
-
-    public void populate_timespan(Conversation conversation, DateTime from, DateTime to) {
-        Gee.List<FileTransfer> transfers = stream_interactor.get_module(FileManager.IDENTITY).get_file_transfers(conversation.account, conversation.counterpart, from, to);
-        foreach (FileTransfer transfer in transfers) {
-            insert_file(transfer);
-        }
-    }
-
-    public void populate_between_widgets(Conversation conversation, DateTime from, DateTime to) { }
-
-    private void insert_file(FileTransfer transfer) {
-        Plugins.MetaConversationItem item = null;
-        if (transfer.mime_type != null && transfer.mime_type.has_prefix("image")) {
-            item = new ImageDisplay(stream_interactor, transfer);
-        } else {
-            item = new DefaultFileDisplay(stream_interactor, transfer);
-        }
-        item_collection.insert_item(item);
-    }
-}
-
-}
diff --git a/main/src/ui/conversation_summary/image_display.vala b/main/src/ui/conversation_summary/image_display.vala
deleted file mode 100644
index 15880836..00000000
--- a/main/src/ui/conversation_summary/image_display.vala
+++ /dev/null
@@ -1,137 +0,0 @@
-using Gtk;
-
-using Dino.Entities;
-using Xmpp;
-
-namespace Dino.Ui.ConversationSummary {
-
-public class ImageDisplay : Plugins.MetaConversationItem {
-    public override Jid? jid { get; set; }
-    public override DateTime? sort_time { get; set; }
-    public override DateTime? display_time { get; set; }
-    public override Encryption? encryption { get; set; }
-    public override Entities.Message.Marked? mark { get; set; }
-
-    public override bool can_merge { get; set; default=true; }
-    public override bool requires_avatar { get; set; default=true; }
-    public override bool requires_header { get; set; default=true; }
-
-    private const int MAX_HEIGHT = 300;
-    private const int MAX_WIDTH = 600;
-
-    private StreamInteractor stream_interactor;
-    private FileTransfer file_transfer;
-
-    public ImageDisplay(StreamInteractor stream_interactor, FileTransfer file_transfer) {
-        this.stream_interactor = stream_interactor;
-        this.file_transfer = file_transfer;
-
-        this.jid = file_transfer.direction == FileTransfer.DIRECTION_SENT ? file_transfer.account.bare_jid.with_resource(file_transfer.account.resourcepart) : file_transfer.counterpart;
-        this.sort_time = file_transfer.time;
-        this.seccondary_sort_indicator = file_transfer.id + 0.2903;
-        this.display_time = file_transfer.time;
-        this.encryption = file_transfer.encryption;
-        this.mark = file_to_message_state(file_transfer.state);
-        file_transfer.notify["state"].connect_after(() => {
-            this.mark = file_to_message_state(file_transfer.state);
-        });
-    }
-
-    public override Object? get_widget(Plugins.WidgetType widget_type) {
-        Image image = new Image() { halign=Align.START, visible = true };
-        Gdk.Pixbuf pixbuf;
-        try {
-            pixbuf = new Gdk.Pixbuf.from_file(file_transfer.get_file().get_path());
-        } catch (Error error) {
-            return null;
-        }
-
-        int max_scaled_height = MAX_HEIGHT * image.scale_factor;
-        if (pixbuf.height > max_scaled_height) {
-            pixbuf = pixbuf.scale_simple((int) ((double) max_scaled_height / pixbuf.height * pixbuf.width), max_scaled_height, Gdk.InterpType.BILINEAR);
-        }
-        int max_scaled_width = MAX_WIDTH * image.scale_factor;
-        if (pixbuf.width > max_scaled_width) {
-            pixbuf = pixbuf.scale_simple(max_scaled_width, (int) ((double) max_scaled_width / pixbuf.width * pixbuf.height), Gdk.InterpType.BILINEAR);
-        }
-        pixbuf = crop_corners(pixbuf, 3 * image.get_scale_factor());
-        Util.image_set_from_scaled_pixbuf(image, pixbuf);
-        Util.force_css(image, "* { box-shadow: 0px 0px 2px 0px rgba(0,0,0,0.1); margin: 2px; border-radius: 3px; }");
-
-        Builder builder = new Builder.from_resource("/im/dino/Dino/conversation_summary/image_toolbar.ui");
-        Widget toolbar = builder.get_object("main") as Widget;
-        Util.force_background(toolbar, "rgba(0, 0, 0, 0.5)");
-        Util.force_css(toolbar, "* { padding: 3px; border-radius: 3px; }");
-
-        Label url_label = builder.get_object("url_label") as Label;
-        Util.force_color(url_label, "#eee");
-        update_info(url_label, file_transfer.file_name);
-
-        Image open_image = builder.get_object("open_image") as Image;
-        Util.force_css(open_image, "*:not(:hover) { color: #eee; }");
-        Button open_button = builder.get_object("open_button") as Button;
-        Util.force_css(open_button, "*:hover { background-color: rgba(255,255,255,0.3); border-color: transparent; }");
-        open_button.clicked.connect(() => {
-            try{
-                AppInfo.launch_default_for_uri(file_transfer.get_file().get_uri(), null);
-            } catch (Error err) {
-                print("Tried to open file://" + file_transfer.get_file().get_path() + " " + err.message + "\n");
-            }
-        });
-
-        Revealer toolbar_revealer = new Revealer() { transition_type=RevealerTransitionType.CROSSFADE, transition_duration=400, visible=true };
-        toolbar_revealer.add(toolbar);
-
-        Grid grid = new Grid() { visible=true };
-        grid.attach(toolbar_revealer, 0, 0, 1, 1);
-        grid.attach(image, 0, 0, 1, 1);
-
-        EventBox event_box = new EventBox() { halign=Align.START, visible=true };
-        event_box.add(grid);
-        event_box.enter_notify_event.connect(() => { toolbar_revealer.reveal_child = true; return false; });
-        event_box.leave_notify_event.connect(() => { toolbar_revealer.reveal_child = false; return false; });
-
-        return event_box;
-    }
-
-    private static Gdk.Pixbuf crop_corners(Gdk.Pixbuf pixbuf, double radius = 3) {
-        Cairo.Context ctx = new Cairo.Context(new Cairo.ImageSurface(Cairo.Format.ARGB32, pixbuf.width, pixbuf.height));
-        Gdk.cairo_set_source_pixbuf(ctx, pixbuf, 0, 0);
-        double degrees = Math.PI / 180.0;
-        ctx.new_sub_path();
-        ctx.arc(pixbuf.width - radius, radius, radius, -90 * degrees, 0 * degrees);
-        ctx.arc(pixbuf.width - radius, pixbuf.height - radius, radius, 0 * degrees, 90 * degrees);
-        ctx.arc(radius, pixbuf.height - radius, radius, 90 * degrees, 180 * degrees);
-        ctx.arc(radius, radius, radius, 180 * degrees, 270 * degrees);
-        ctx.close_path();
-        ctx.clip();
-        ctx.paint();
-        return Gdk.pixbuf_get_from_surface(ctx.get_target(), 0, 0, pixbuf.width, pixbuf.height);
-    }
-
-    private void update_info(Label url_label, string? info) {
-        string url = info ?? "";
-        if (url.has_prefix("https://")) url = url.substring(8);
-        if (url.has_prefix("http://")) url = url.substring(7);
-        if (url.has_prefix("www.")) url = url.substring(4);
-        string[] slash_split = url.split("/");
-        if (slash_split.length > 2) url = slash_split[0] + "/…/" + slash_split[slash_split.length - 1];
-        url_label.label = url;
-    }
-
-    private Entities.Message.Marked file_to_message_state(FileTransfer.State state) {
-        switch (state) {
-            case FileTransfer.State.IN_PROCESS:
-                return Entities.Message.Marked.UNSENT;
-            case FileTransfer.State.COMPLETE:
-                return Entities.Message.Marked.NONE;
-            case FileTransfer.State.NOT_STARTED:
-                return Entities.Message.Marked.UNSENT;
-            case FileTransfer.State.FAILED:
-                return Entities.Message.Marked.WONTSEND;
-        }
-        assert_not_reached();
-    }
-}
-
-}
diff --git a/main/src/ui/conversation_summary/message_populator.vala b/main/src/ui/conversation_summary/message_populator.vala
deleted file mode 100644
index b342306b..00000000
--- a/main/src/ui/conversation_summary/message_populator.vala
+++ /dev/null
@@ -1,81 +0,0 @@
-using Gee;
-using Gtk;
-
-using Dino.Entities;
-
-namespace Dino.Ui.ConversationSummary {
-
-public class MessagePopulator : Object {
-
-    private StreamInteractor? stream_interactor;
-    private Conversation? current_conversation;
-    private Plugins.ConversationItemCollection? item_collection;
-    private HashMap<Plugins.MetaConversationItem, Message> meta_message = new HashMap<Plugins.MetaConversationItem, Message>();
-
-    public MessagePopulator(StreamInteractor stream_interactor) {
-        this.stream_interactor = stream_interactor;
-
-        Application app = GLib.Application.get_default() as Application;
-        app.plugin_registry.register_message_display(new DefaultMessageDisplay(stream_interactor));
-        app.plugin_registry.register_message_display(new SlashmeMessageDisplay(stream_interactor));
-
-
-        stream_interactor.get_module(MessageProcessor.IDENTITY).message_received.connect(handle_message);
-        stream_interactor.get_module(MessageProcessor.IDENTITY).message_sent.connect(handle_message);
-    }
-
-    public void init(Conversation conversation, Plugins.ConversationItemCollection item_collection) {
-        current_conversation = conversation;
-        this.item_collection = item_collection;
-    }
-
-    public void close(Conversation conversation) { }
-
-    public void populate_latest(Conversation conversation, int n) {
-        Gee.List<Entities.Message>? messages = stream_interactor.get_module(MessageStorage.IDENTITY).get_messages(conversation, n);
-        if (messages != null) {
-            foreach (Entities.Message message in messages) {
-                handle_message(message, conversation);
-            }
-        }
-    }
-
-    public void populate_before(Conversation conversation, Plugins.MetaConversationItem item, int n) {
-        Gee.List<Entities.Message>? messages = stream_interactor.get_module(MessageStorage.IDENTITY).get_messages_before_message(conversation, meta_message[item], n);
-        if (messages != null) {
-            foreach (Entities.Message message in messages) {
-                handle_message(message, conversation);
-            }
-        }
-    }
-
-    private void handle_message(Message message, Conversation conversation) {
-        if (!conversation.equals(current_conversation)) return;
-
-        Plugins.MessageDisplayProvider? best_provider = null;
-        double priority = -1;
-        Application app = GLib.Application.get_default() as Application;
-        foreach (Plugins.MessageDisplayProvider provider in app.plugin_registry.message_displays) {
-            if (provider.can_display(message) && provider.priority > priority) {
-                best_provider = provider;
-                priority = provider.priority;
-            }
-        }
-        Plugins.MetaConversationItem? meta_item = best_provider.get_item(message, conversation);
-        if (meta_item == null) return;
-        meta_message[meta_item] = message;
-
-        meta_item.mark = message.marked;
-        WeakRef weak_meta_item = WeakRef(meta_item);
-        WeakRef weak_message = WeakRef(message);
-        message.notify["marked"].connect(() => {
-            Plugins.MetaConversationItem? mi = weak_meta_item.get() as Plugins.MetaConversationItem;
-            Message? m = weak_message.get() as Message;
-            if (mi == null || m == null) return;
-            mi.mark = m.marked;
-        });
-        item_collection.insert_item(meta_item);
-    }
-}
-
-}
diff --git a/main/src/ui/conversation_summary/message_textview.vala b/main/src/ui/conversation_summary/message_textview.vala
index 0b5ed6e4..0c38c269 100644
--- a/main/src/ui/conversation_summary/message_textview.vala
+++ b/main/src/ui/conversation_summary/message_textview.vala
@@ -60,7 +60,7 @@ public class MessageTextView : TextView {
             TextIter end_iter;
             buffer.get_iter_at_offset(out start_iter, start);
             buffer.get_iter_at_offset(out end_iter, end);
-            buffer.apply_tag_by_name("semibold", start_iter, end_iter);
+            buffer.apply_tag(bold_tag, start_iter, end_iter);
         }
     }
 
@@ -125,7 +125,7 @@ public class MessageTextView : TextView {
             TextIter end_iter;
             buffer.get_iter_at_offset(out start_iter, absolute_start + start);
             buffer.get_iter_at_offset(out end_iter, absolute_start + end);
-            buffer.apply_tag_by_name("url", start_iter, end_iter);
+            buffer.apply_tag(link_tag, start_iter, end_iter);
         }
     }
 
diff --git a/main/src/ui/conversation_summary/slashme_message_display.vala b/main/src/ui/conversation_summary/slashme_message_display.vala
deleted file mode 100644
index 1ee20748..00000000
--- a/main/src/ui/conversation_summary/slashme_message_display.vala
+++ /dev/null
@@ -1,79 +0,0 @@
-using Gtk;
-
-using Dino.Entities;
-using Xmpp;
-
-namespace Dino.Ui.ConversationSummary {
-
-public class SlashmeMessageDisplay : Plugins.MessageDisplayProvider, Object {
-    public string id { get; set; default="slashme"; }
-    public double priority { get; set; default=1; }
-
-    public StreamInteractor stream_interactor;
-
-    public SlashmeMessageDisplay(StreamInteractor stream_interactor) {
-        this.stream_interactor = stream_interactor;
-    }
-
-    public bool can_display(Entities.Message? message) {
-        return message.body.has_prefix("/me");
-    }
-
-    public Plugins.MetaConversationItem? get_item(Entities.Message message, Conversation conversation) {
-        return new MetaSlashmeItem(stream_interactor, message, conversation);
-    }
-}
-
-public class MetaSlashmeItem : Plugins.MetaConversationItem {
-    public override Jid? jid { get; set; }
-    public override DateTime? sort_time { get; set; }
-    public override DateTime? display_time { get; set; }
-    public override Encryption? encryption { get; set; }
-
-    private StreamInteractor stream_interactor;
-    private Conversation conversation;
-    private Message message;
-    private TextTag nick_tag;
-    private MessageTextView text_view;
-
-    public MetaSlashmeItem(StreamInteractor stream_interactor, Message message, Conversation conversation) {
-        this.stream_interactor = stream_interactor;
-        this.conversation = conversation;
-        this.message = message;
-        this.jid = message.from;
-        this.sort_time = message.local_time;
-        this.seccondary_sort_indicator = message.id + 0.0845;
-        this.display_time = message.time;
-        this.encryption = message.encryption;
-    }
-
-    public override bool can_merge { get; set; default=false; }
-    public override bool requires_avatar { get; set; default=true; }
-    public override bool requires_header { get; set; default=false; }
-
-    public override Object? get_widget(Plugins.WidgetType widget_type) {
-        text_view = new MessageTextView() { valign=Align.CENTER, vexpand=true, visible = true };
-        if (conversation.type_ == Conversation.Type.GROUPCHAT)  {
-            text_view.highlight_word(conversation.nickname);
-        }
-
-        string display_name = Util.get_message_display_name(stream_interactor, message, conversation.account);
-        string color = Util.get_name_hex_color(stream_interactor, conversation.account, conversation.counterpart, Util.is_dark_theme(text_view));
-        nick_tag = text_view.buffer.create_tag("nick", foreground: "#" + color);
-        TextIter iter;
-        text_view.buffer.get_start_iter(out iter);
-        text_view.buffer.insert_with_tags(ref iter, display_name, display_name.length, nick_tag);
-        text_view.add_text(message.body.substring(3));
-
-        text_view.style_updated.connect(update_style);
-        text_view.realize.connect(update_style);
-        return text_view;
-    }
-
-    private void update_style() {
-        string color = Util.get_name_hex_color(stream_interactor, conversation.account, message.real_jid ?? message.from, Util.is_dark_theme(text_view));
-        nick_tag.foreground = "#" + color;
-    }
-}
-
-}