Refactor file receive/send interfaces and UI

5 files changed, 237 insertions, 204 deletions

diff --git a/plugins/http-files/src/file_provider.vala b/plugins/http-files/src/file_provider.vala
index b7d18e36..38687863 100644
--- a/plugins/http-files/src/file_provider.vala
+++ b/plugins/http-files/src/file_provider.vala
@@ -7,16 +7,15 @@ using Xmpp;
 namespace Dino.Plugins.HttpFiles {
 
 public class FileProvider : Dino.FileProvider, Object {
-    public string id { get { return "http"; } }
 
     private StreamInteractor stream_interactor;
     private Dino.Database dino_db;
-    private Regex url_regex;
+    private Regex url_regex = /^(?i)\b((?:[a-z][\w-]+:(?:\/{1,3}|[a-z0-9%])|www\d{0,3}[.]|[a-z0-9.\-]+[.][a-z]{2,4}\/)(?:[^\s()<>]+|\(([^\s()<>]+|(\([^\s()<>]+\)))*\))+(?:\(([^\s()<>]+|(\([^\s()<>]+\)))*\)|[^\s`!()\[\]{};:'".,<>?«»“”‘’]))$/;
+    private Regex omemo_url_regex = /^aesgcm:\/\/(.*)#(([A-Fa-f0-9]{2}){48}|([A-Fa-f0-9]{2}){44})$/;
 
     public FileProvider(StreamInteractor stream_interactor, Dino.Database dino_db) {
         this.stream_interactor = stream_interactor;
         this.dino_db = dino_db;
-        this.url_regex = /^(?i)\b((?:[a-z][\w-]+:(?:\/{1,3}|[a-z0-9%])|www\d{0,3}[.]|[a-z0-9.\-]+[.][a-z]{2,4}\/)(?:[^\s()<>]+|\(([^\s()<>]+|(\([^\s()<>]+\)))*\))+(?:\(([^\s()<>]+|(\([^\s()<>]+\)))*\)|[^\s`!()\[\]{};:'".,<>?«»“”‘’]))$/;
 
         stream_interactor.get_module(MessageProcessor.IDENTITY).received_pipeline.connect(new ReceivedMessageListener(this));
     }
@@ -38,7 +37,11 @@ public class FileProvider : Dino.FileProvider, Object {
         public override async bool run(Entities.Message message, Xmpp.MessageStanza stanza, Conversation conversation) {
             if (outer.url_regex.match(message.body)) {
                 string? oob_url = Xmpp.Xep.OutOfBandData.get_url_from_message(stanza);
-                if (oob_url != null && oob_url == message.body) {
+
+                bool normal_file = oob_url != null && oob_url == message.body;
+                bool omemo_file = outer.omemo_url_regex.match(message.body);
+
+                if (normal_file || omemo_file) {
                     yield outer.on_file_message(message, conversation);
                 }
             }
@@ -47,83 +50,102 @@ public class FileProvider : Dino.FileProvider, Object {
     }
 
     private async void on_file_message(Entities.Message message, Conversation conversation) {
-        FileTransfer file_transfer = new FileTransfer();
-        file_transfer.account = conversation.account;
-        file_transfer.counterpart = message.counterpart;
-        file_transfer.ourpart = message.ourpart;
-        file_transfer.encryption = Encryption.NONE;
-        file_transfer.time = message.time;
-        file_transfer.local_time = message.local_time;
-        file_transfer.direction = message.direction;
-        file_transfer.file_name = message.body.substring(message.body.last_index_of("/") + 1);
-        file_transfer.size = -1;
-        file_transfer.state = FileTransfer.State.NOT_STARTED;
-        file_transfer.provider = 0;
-        file_transfer.info = message.id.to_string();
-
-        if (stream_interactor.get_module(FileManager.IDENTITY).is_sender_trustworthy(file_transfer, conversation)) {
-            yield get_meta_info(file_transfer);
-            if (file_transfer.size >= 0 && file_transfer.size < 5000000) {
-                ContentItem? content_item = stream_interactor.get_module(ContentItemStore.IDENTITY).get_item(conversation, 1, message.id);
-                if (content_item != null) {
-                    stream_interactor.get_module(ContentItemStore.IDENTITY).set_item_hide(content_item, true);
-                }
-            }
-            file_incoming(file_transfer, conversation);
+        // Hide message
+        ContentItem? content_item = stream_interactor.get_module(ContentItemStore.IDENTITY).get_item(conversation, 1, message.id);
+        if (content_item != null) {
+            stream_interactor.get_module(ContentItemStore.IDENTITY).set_item_hide(content_item, true);
         }
+
+        var additional_info = message.id.to_string();
+
+        var receive_data = new HttpFileReceiveData();
+        receive_data.url = message.body;
+
+        var file_meta = new HttpFileMeta();
+        file_meta.file_name = Uri.unescape_string(message.body.substring(message.body.last_index_of("/") + 1));
+        file_meta.message = message;
+
+        file_incoming(additional_info, message.from, message.time, message.local_time, conversation, receive_data, file_meta);
     }
 
-    public async void get_meta_info(FileTransfer file_transfer) {
-        string url_body = dino_db.message.select({dino_db.message.body}).with(dino_db.message.id, "=", int.parse(file_transfer.info))[dino_db.message.body];
+    public async FileMeta get_meta_info(FileTransfer file_transfer, FileReceiveData receive_data, FileMeta file_meta) throws FileReceiveError {
+        HttpFileReceiveData? http_receive_data = receive_data as HttpFileReceiveData;
+        if (http_receive_data == null) return file_meta;
+
         var session = new Soup.Session();
-        var head_message = new Soup.Message("HEAD", url_body);
+        var head_message = new Soup.Message("HEAD", http_receive_data.url);
+
         if (head_message != null) {
-            yield session.send_async(head_message, null);
+            try {
+                yield session.send_async(head_message, null);
+            } catch (Error e) {
+                throw new FileReceiveError.GET_METADATA_FAILED("HEAD request failed");
+            }
 
             string? content_type = null, content_length = null;
-            print(url_body + ":\n");
             head_message.response_headers.foreach((name, val) => {
-                print(name + " " + val + "\n");
                 if (name == "Content-Type") content_type = val;
                 if (name == "Content-Length") content_length = val;
             });
-            file_transfer.mime_type = content_type;
+            file_meta.mime_type = content_type;
             if (content_length != null) {
-                file_transfer.size = int.parse(content_length);
+                file_meta.size = int.parse(content_length);
             }
         }
+
+        return file_meta;
     }
 
-    public async void download(FileTransfer file_transfer, File file_) {
+    public async InputStream download(FileTransfer file_transfer, FileReceiveData receive_data, FileMeta file_meta) throws FileReceiveError {
+        HttpFileReceiveData? http_receive_data = receive_data as HttpFileReceiveData;
+        if (http_receive_data == null) assert(false);
+
         try {
-            File file = file_;
-            string url_body = dino_db.message.select({dino_db.message.body}).with(dino_db.message.id, "=", int.parse(file_transfer.info))[dino_db.message.body];
             var session = new Soup.Session();
-            Soup.Request request = session.request(url_body);
+            Soup.Request request = session.request(http_receive_data.url);
 
-            file_transfer.input_stream = yield request.send_async(null);
+            return yield request.send_async(null);
+        } catch (Error e) {
+            throw new FileReceiveError.DOWNLOAD_FAILED("Downloading file error: %s".printf(e.message));
+        }
+    }
 
-            foreach (IncomingFileProcessor processor in stream_interactor.get_module(FileManager.IDENTITY).incoming_processors) {
-                if (processor.can_process(file_transfer)) {
-                    processor.process(file_transfer);
-                }
-            }
+    public FileMeta get_file_meta(FileTransfer file_transfer) throws FileReceiveError {
+        Conversation? conversation = stream_interactor.get_module(ConversationManager.IDENTITY).get_conversation(file_transfer.counterpart.bare_jid, file_transfer.account);
+        if (conversation == null) throw new FileReceiveError.GET_METADATA_FAILED("No conversation");
 
-            if (file_transfer.encryption == Encryption.PGP || file.get_path().has_suffix(".pgp")) {
-                file = File.new_for_path(file.get_path().substring(0, file.get_path().length - 4));
-            }
+        Message? message = stream_interactor.get_module(MessageStorage.IDENTITY).get_message_by_id(int.parse(file_transfer.info), conversation);
+        if (message == null) throw new FileReceiveError.GET_METADATA_FAILED("No message");
 
-            OutputStream os = file.create(FileCreateFlags.REPLACE_DESTINATION);
-            yield os.splice_async(file_transfer.input_stream, 0);
-            os.close();
-            file_transfer.path = file.get_basename();
-            file_transfer.input_stream = yield file.read_async();
+        var file_meta = new HttpFileMeta();
+        file_meta.size = file_transfer.size;
+        file_meta.mime_type = file_transfer.mime_type;
 
-            file_transfer.state = FileTransfer.State.COMPLETE;
-        } catch (Error e) {
-            file_transfer.state = FileTransfer.State.FAILED;
+        // Extract file name from URL
+        file_meta.file_name = Uri.unescape_string(message.body.substring(message.body.last_index_of("/") + 1));
+        if (file_meta.file_name.contains("#")) {
+            file_meta.file_name = file_meta.file_name.substring(0, file_meta.file_name.last_index_of("#"));
         }
+
+        file_meta.message = message;
+
+        return file_meta;
     }
+
+    public FileReceiveData? get_file_receive_data(FileTransfer file_transfer) {
+        Conversation? conversation = stream_interactor.get_module(ConversationManager.IDENTITY).get_conversation(file_transfer.counterpart.bare_jid, file_transfer.account);
+        if (conversation == null) return null;
+
+        Message? message = stream_interactor.get_module(MessageStorage.IDENTITY).get_message_by_id(int.parse(file_transfer.info), conversation);
+        if (message == null) return null;
+
+        var receive_data = new HttpFileReceiveData();
+        receive_data.url = message.body;
+
+        return receive_data;
+    }
+
+    public int get_id() { return 0; }
 }
 
 }
diff --git a/plugins/http-files/src/file_sender.vala b/plugins/http-files/src/file_sender.vala
new file mode 100644
index 00000000..ce40d2f8
--- /dev/null
+++ b/plugins/http-files/src/file_sender.vala
@@ -0,0 +1,126 @@
+using Dino.Entities;
+using Xmpp;
+using Gee;
+
+namespace Dino.Plugins.HttpFiles {
+
+public class HttpFileSender : FileSender, Object {
+    private StreamInteractor stream_interactor;
+    private Database db;
+    private HashMap<Account, long> max_file_sizes = new HashMap<Account, long>(Account.hash_func, Account.equals_func);
+
+    public HttpFileSender(StreamInteractor stream_interactor, Database db) {
+        this.stream_interactor = stream_interactor;
+        this.db = db;
+
+        stream_interactor.stream_negotiated.connect(on_stream_negotiated);
+        stream_interactor.get_module(MessageProcessor.IDENTITY).build_message_stanza.connect(check_add_oob);
+    }
+
+    public async FileSendData? prepare_send_file(Conversation conversation, FileTransfer file_transfer) throws FileSendError {
+        HttpFileSendData send_data = new HttpFileSendData();
+        if (send_data == null) return null;
+
+        Xmpp.XmppStream? stream = stream_interactor.get_stream(file_transfer.account);
+        if (stream == null) return null;
+
+        try {
+            var slot_result = yield stream_interactor.module_manager.get_module(file_transfer.account, Xmpp.Xep.HttpFileUpload.Module.IDENTITY).request_slot(stream, file_transfer.server_file_name, file_transfer.size, file_transfer.mime_type);
+            send_data.url_down = slot_result.url_get;
+            send_data.url_up = slot_result.url_put;
+        } catch (Xep.HttpFileUpload.HttpFileTransferError e) {
+            throw new FileSendError.UPLOAD_FAILED("Http file upload XMPP error: %s".printf(e.message));
+        }
+
+        return send_data;
+    }
+
+    public async void send_file(Conversation conversation, FileTransfer file_transfer, FileSendData file_send_data) throws FileSendError {
+        HttpFileSendData? send_data = file_send_data as HttpFileSendData;
+        if (send_data == null) return;
+
+        yield upload(file_transfer, send_data);
+
+        file_transfer.info = send_data.url_down; // store the message content temporarily so the message gets filtered out
+
+        Entities.Message message = stream_interactor.get_module(MessageProcessor.IDENTITY).create_out_message(send_data.url_down, conversation);
+
+        message.encryption = send_data.encrypt_message ? conversation.encryption : Encryption.NONE;
+        stream_interactor.get_module(MessageProcessor.IDENTITY).send_message(message, conversation);
+
+        file_transfer.info = message.id.to_string();
+
+        ContentItem? content_item = stream_interactor.get_module(ContentItemStore.IDENTITY).get_item(conversation, 1, message.id);
+        if (content_item != null) {
+            stream_interactor.get_module(ContentItemStore.IDENTITY).set_item_hide(content_item, true);
+        }
+    }
+
+    public bool can_send(Conversation conversation, FileTransfer file_transfer) {
+        if (!max_file_sizes.has_key(conversation.account)) return false;
+
+        return file_transfer.size < max_file_sizes[conversation.account];
+    }
+
+    public bool is_upload_available(Conversation conversation) {
+        lock (max_file_sizes) {
+            return max_file_sizes.has_key(conversation.account);
+        }
+    }
+
+    public long get_max_file_size(Account account) {
+        lock (max_file_sizes) {
+            return max_file_sizes[account];
+        }
+    }
+
+    private async void upload(FileTransfer file_transfer, HttpFileSendData file_send_data) throws FileSendError {
+        Xmpp.XmppStream? stream = stream_interactor.get_stream(file_transfer.account);
+        if (stream == null) return;
+
+        uint8[] buf = new uint8[256];
+        Array<uint8> data = new Array<uint8>(false, true, 0);
+        size_t len = -1;
+        do {
+            try {
+                len = file_transfer.input_stream.read(buf);
+            } catch (IOError e) {
+                throw new FileSendError.UPLOAD_FAILED("HTTP upload: IOError reading stream: %s".printf(e.message));
+            }
+            data.append_vals(buf, (uint) len);
+        } while(len > 0);
+
+        Soup.Message message = new Soup.Message("PUT", file_send_data.url_up);
+        message.set_request(file_transfer.mime_type, Soup.MemoryUse.COPY, data.data);
+        Soup.Session session = new Soup.Session();
+        try {
+            yield session.send_async(message);
+            if (message.status_code < 200 && message.status_code >= 300) {
+                throw new FileSendError.UPLOAD_FAILED("HTTP status code %s".printf(message.status_code.to_string()));
+            }
+        } catch (Error e) {
+            throw new FileSendError.UPLOAD_FAILED("HTTP upload error: %s".printf(e.message));
+        }
+    }
+
+    private void on_stream_negotiated(Account account, XmppStream stream) {
+        stream_interactor.module_manager.get_module(account, Xmpp.Xep.HttpFileUpload.Module.IDENTITY).feature_available.connect((stream, max_file_size) => {
+            lock (max_file_sizes) {
+                max_file_sizes[account] = max_file_size;
+            }
+            upload_available(account);
+        });
+    }
+
+    private void check_add_oob(Entities.Message message, Xmpp.MessageStanza message_stanza, Conversation conversation) {
+        if (message.encryption == Encryption.NONE && message_is_file(db, message) && message.body.has_prefix("http")) {
+            Xep.OutOfBandData.add_url_to_message(message_stanza, message_stanza.body);
+        }
+    }
+
+    public int get_id() { return 0; }
+
+    public float get_priority() { return 100; }
+}
+
+}
diff --git a/plugins/http-files/src/manager.vala b/plugins/http-files/src/manager.vala
deleted file mode 100644
index 2f702be3..00000000
--- a/plugins/http-files/src/manager.vala
+++ /dev/null
@@ -1,147 +0,0 @@
-using Dino.Entities;
-using Xmpp;
-using Gee;
-
-namespace Dino.Plugins.HttpFiles {
-
-public class Manager : StreamInteractionModule, FileSender, Object {
-    public static ModuleIdentity<Manager> IDENTITY = new ModuleIdentity<Manager>("http_files");
-    public string id { get { return IDENTITY.id; } }
-
-    public signal void uploading(FileTransfer file_transfer);
-    public signal void uploaded(FileTransfer file_transfer, string url);
-
-    private StreamInteractor stream_interactor;
-    private Database db;
-    private HashMap<Account, long> max_file_sizes = new HashMap<Account, long>(Account.hash_func, Account.equals_func);
-
-    public static void start(StreamInteractor stream_interactor, Database db) {
-        Manager m = new Manager(stream_interactor, db);
-        stream_interactor.add_module(m);
-    }
-
-    private Manager(StreamInteractor stream_interactor, Database db) {
-        this.stream_interactor = stream_interactor;
-        this.db = db;
-
-        stream_interactor.get_module(FileManager.IDENTITY).add_sender(this);
-        stream_interactor.stream_negotiated.connect(on_stream_negotiated);
-        stream_interactor.get_module(MessageProcessor.IDENTITY).build_message_stanza.connect(check_add_oob);
-    }
-
-    public delegate void OnUploadOk(XmppStream stream, string url_down);
-    public delegate void OnError(XmppStream stream, string error);
-    public void upload(XmppStream stream, FileTransfer file_transfer, owned OnUploadOk listener, owned OnError error_listener) {
-        uint8[] buf = new uint8[256];
-        Array<uint8> data = new Array<uint8>(false, true, 0);
-        size_t len = -1;
-        do {
-            try {
-                len = file_transfer.input_stream.read(buf);
-            } catch (IOError error) {
-                error_listener(stream, @"HTTP upload: IOError reading stream: $(error.message)");
-            }
-            data.append_vals(buf, (uint) len);
-        } while(len > 0);
-
-        stream_interactor.module_manager.get_module(file_transfer.account, Xmpp.Xep.HttpFileUpload.Module.IDENTITY).request_slot(stream, file_transfer.server_file_name, (int) data.length, file_transfer.mime_type,
-            (stream, url_down, url_up) => {
-                Soup.Message message = new Soup.Message("PUT", url_up);
-                message.set_request(file_transfer.mime_type, Soup.MemoryUse.COPY, data.data);
-                Soup.Session session = new Soup.Session();
-                session.send_async.begin(message, null, (obj, res) => {
-                    try {
-                        session.send_async.end(res);
-                        if (message.status_code >= 200 && message.status_code < 300) {
-                            listener(stream, url_down);
-                        } else {
-                            error_listener(stream, "HTTP status code " + message.status_code.to_string());
-                        }
-                    } catch (Error e) {
-                        error_listener(stream, e.message);
-                    }
-                });
-            },
-            (stream, error) => error_listener(stream, error));
-    }
-
-    public void send_file(Conversation conversation, FileTransfer file_transfer) {
-        Xmpp.XmppStream? stream = stream_interactor.get_stream(file_transfer.account);
-        if (stream != null) {
-            upload(stream, file_transfer,
-                (stream, url_down) => {
-                    uploaded(file_transfer, url_down);
-                    file_transfer.info = url_down; // store the message content temporarily so the message gets filtered out
-                    Entities.Message message = stream_interactor.get_module(MessageProcessor.IDENTITY).create_out_message(url_down, conversation);
-                    message.encryption = Encryption.NONE;
-                    stream_interactor.get_module(MessageProcessor.IDENTITY).send_message(message, conversation);
-                    file_transfer.info = message.id.to_string();
-
-                    ContentItem? content_item = stream_interactor.get_module(ContentItemStore.IDENTITY).get_item(conversation, 1, message.id);
-                    if (content_item != null) {
-                        stream_interactor.get_module(ContentItemStore.IDENTITY).set_item_hide(content_item, true);
-                    }
-                },
-                (stream, error_str) => {
-                    warning("Failed getting upload url: %s", error_str);
-                    file_transfer.state = FileTransfer.State.FAILED;
-                }
-            );
-        }
-    }
-
-    public bool can_send(Conversation conversation, FileTransfer file_transfer) {
-        return file_transfer.encryption != Encryption.OMEMO;
-    }
-
-    public bool is_upload_available(Conversation conversation) {
-        lock (max_file_sizes) {
-            return max_file_sizes.has_key(conversation.account);
-        }
-    }
-
-    public long get_max_file_size(Account account) {
-        lock (max_file_sizes) {
-            return max_file_sizes[account];
-        }
-    }
-
-    private void on_stream_negotiated(Account account, XmppStream stream) {
-        stream_interactor.module_manager.get_module(account, Xmpp.Xep.HttpFileUpload.Module.IDENTITY).feature_available.connect((stream, max_file_size) => {
-            lock (max_file_sizes) {
-                max_file_sizes[account] = max_file_size;
-            }
-            upload_available(account);
-        });
-    }
-
-    private void check_add_oob(Entities.Message message, Xmpp.MessageStanza message_stanza, Conversation conversation) {
-        if (message_is_file(db, message) && message.body.has_prefix("http")) {
-            Xep.OutOfBandData.add_url_to_message(message_stanza, message_stanza.body);
-        }
-    }
-}
-
-public class FileMessageFilter : ContentFilter, Object {
-    public Database db;
-
-    public FileMessageFilter(Dino.Database db) {
-        this.db = db;
-    }
-
-    public bool discard(ContentItem content_item) {
-        if (content_item.type_ == MessageItem.TYPE) {
-            MessageItem message_item = content_item as MessageItem;
-            return message_is_file(db, message_item.message);
-        }
-        return false;
-    }
-}
-
-private bool message_is_file(Database db, Entities.Message message) {
-    Qlite.QueryBuilder builder = db.file_transfer.select({db.file_transfer.id}).with(db.file_transfer.info, "=", message.id.to_string());
-    Qlite.QueryBuilder builder2 = db.file_transfer.select({db.file_transfer.id}).with(db.file_transfer.info, "=", message.body);
-    return builder.count() > 0 || builder2.count() > 0;
-}
-
-}
diff --git a/plugins/http-files/src/message_filter.vala b/plugins/http-files/src/message_filter.vala
new file mode 100644
index 00000000..01035c4c
--- /dev/null
+++ b/plugins/http-files/src/message_filter.vala
@@ -0,0 +1,23 @@
+using Dino.Entities;
+using Xmpp;
+using Gee;
+
+namespace Dino.Plugins.HttpFiles {
+
+public class FileMessageFilter : ContentFilter, Object {
+    public Database db;
+
+    public FileMessageFilter(Dino.Database db) {
+        this.db = db;
+    }
+
+    public bool discard(ContentItem content_item) {
+        if (content_item.type_ == MessageItem.TYPE) {
+            MessageItem message_item = content_item as MessageItem;
+            return message_is_file(db, message_item.message);
+        }
+        return false;
+    }
+}
+
+}
diff --git a/plugins/http-files/src/plugin.vala b/plugins/http-files/src/plugin.vala
index e2ce5ad9..bdf48770 100644
--- a/plugins/http-files/src/plugin.vala
+++ b/plugins/http-files/src/plugin.vala
@@ -7,14 +7,17 @@ public class Plugin : RootInterface, Object {
 
     public Dino.Application app;
     public FileProvider file_provider;
+    public FileSender file_sender;
 
     public void registered(Dino.Application app) {
         this.app = app;
-        Manager.start(this.app.stream_interactor, app.db);
 
         file_provider = new FileProvider(app.stream_interactor, app.db);
+        file_sender = new HttpFileSender(app.stream_interactor, app.db);
 
         app.stream_interactor.get_module(FileManager.IDENTITY).add_provider(file_provider);
+        app.stream_interactor.get_module(FileManager.IDENTITY).add_sender(file_sender);
+
         app.stream_interactor.get_module(ContentItemStore.IDENTITY).add_filter(new FileMessageFilter(app.db));
     }
 
@@ -23,4 +26,10 @@ public class Plugin : RootInterface, Object {
     }
 }
 
+private bool message_is_file(Database db, Entities.Message message) {
+    Qlite.QueryBuilder builder = db.file_transfer.select({db.file_transfer.id}).with(db.file_transfer.info, "=", message.id.to_string());
+    Qlite.QueryBuilder builder2 = db.file_transfer.select({db.file_transfer.id}).with(db.file_transfer.info, "=", message.body);
+    return builder.count() > 0 || builder2.count() > 0;
+}
+
 }