Show which account is currently used in conversation details in the about sectionadd_conversation_account_indicator

4 files changed, 213 insertions, 2 deletions

diff --git a/plugins/openpgp/src/account_settings_entry.vala b/plugins/openpgp/src/account_settings_entry.vala
index d2e5ac23..7c99942f 100644
--- a/plugins/openpgp/src/account_settings_entry.vala
+++ b/plugins/openpgp/src/account_settings_entry.vala
@@ -116,8 +116,10 @@ public class AccountSettingsEntry : Plugins.AccountSettingsEntry {
         SourceFunc callback = fetch_keys.callback;
         new Thread<void*> (null, () => { // Querying GnuPG might take some time
             try {
-            keys = GPGHelper.get_keylist(null, true);
-        } catch (Error e) { }
+                keys = GPGHelper.get_keylist(null, true);
+            } catch (Error e) {
+                warning(e.message);
+            }
             Idle.add((owned)callback);
             return null;
         });
diff --git a/plugins/openpgp/src/gpgme_fix.c b/plugins/openpgp/src/gpgme_fix.c
new file mode 100644
index 00000000..bf457a6c
--- /dev/null
+++ b/plugins/openpgp/src/gpgme_fix.c
@@ -0,0 +1,12 @@
+#include <gpgme_fix.h>
+
+GRecMutex gpgme_global_mutex = {0};
+
+gpgme_key_t gpgme_key_ref_vapi (gpgme_key_t key) {
+    gpgme_key_ref(key);
+    return key;
+}
+gpgme_key_t gpgme_key_unref_vapi (gpgme_key_t key) {
+    gpgme_key_unref(key);
+    return key;
+}
diff --git a/plugins/openpgp/src/gpgme_fix.h b/plugins/openpgp/src/gpgme_fix.h
new file mode 100644
index 00000000..714614fc
--- /dev/null
+++ b/plugins/openpgp/src/gpgme_fix.h
@@ -0,0 +1,12 @@
+#ifndef GPGME_FIX
+#define GPGME_FIX 1
+
+#include <glib.h>
+#include <gpgme.h>
+
+extern GRecMutex gpgme_global_mutex;
+
+gpgme_key_t gpgme_key_ref_vapi (gpgme_key_t key);
+gpgme_key_t gpgme_key_unref_vapi (gpgme_key_t key);
+
+#endif
diff --git a/plugins/openpgp/src/gpgme_helper.vala b/plugins/openpgp/src/gpgme_helper.vala
new file mode 100644
index 00000000..18d07c06
--- /dev/null
+++ b/plugins/openpgp/src/gpgme_helper.vala
@@ -0,0 +1,185 @@
+using Gee;
+using GPG;
+
+namespace GPGHelper {
+
+private static bool initialized = false;
+
+public static string encrypt_armor(string plain, Key[] keys, EncryptFlags flags) throws GLib.Error {
+    global_mutex.lock();
+    try {
+        initialize();
+        Data plain_data = Data.create_from_memory(plain.data, false);
+        Context context = Context.create();
+        context.set_armor(true);
+        Data enc_data = context.op_encrypt(keys, flags, plain_data);
+        return get_string_from_data(enc_data);
+    } finally {
+        global_mutex.unlock();
+    }
+}
+
+public static uint8[] encrypt_file(string uri, Key[] keys, EncryptFlags flags, string file_name) throws GLib.Error {
+    global_mutex.lock();
+    try {
+        initialize();
+        Data plain_data = Data.create_from_file(uri);
+        plain_data.set_file_name(file_name);
+        Context context = Context.create();
+        context.set_armor(true);
+        Data enc_data = context.op_encrypt(keys, flags, plain_data);
+        return get_uint8_from_data(enc_data);
+    } finally {
+        global_mutex.unlock();
+    }
+}
+
+public static string decrypt(string encr) throws GLib.Error {
+    global_mutex.lock();
+    try {
+        initialize();
+        Data enc_data = Data.create_from_memory(encr.data, false);
+        Context context = Context.create();
+        Data dec_data = context.op_decrypt(enc_data);
+        return get_string_from_data(dec_data);
+    } finally {
+        global_mutex.unlock();
+    }
+}
+
+public class DecryptedData {
+    public uint8[] data { get; set; }
+    public string filename { get; set; }
+}
+
+public static DecryptedData decrypt_data(uint8[] data) throws GLib.Error {
+    global_mutex.lock();
+    try {
+        initialize();
+        Data enc_data = Data.create_from_memory(data, false);
+        Context context = Context.create();
+        Data dec_data = context.op_decrypt(enc_data);
+        DecryptResult* dec_res = context.op_decrypt_result();
+        return new DecryptedData() { data=get_uint8_from_data(dec_data), filename=dec_res->file_name};
+    } finally {
+        global_mutex.unlock();
+    }
+}
+
+public static string sign(string plain, SigMode mode, Key? key = null) throws GLib.Error {
+    global_mutex.lock();
+    try {
+        initialize();
+        Data plain_data = Data.create_from_memory(plain.data, false);
+        Context context = Context.create();
+        if (key != null) context.signers_add(key);
+        Data signed_data = context.op_sign(plain_data, mode);
+        return get_string_from_data(signed_data);
+    } finally {
+        global_mutex.unlock();
+    }
+}
+
+public static string? get_sign_key(string signature, string? text) throws GLib.Error {
+    global_mutex.lock();
+    try {
+        initialize();
+        Data sig_data = Data.create_from_memory(signature.data, false);
+        Data text_data;
+        if (text != null) {
+            text_data = Data.create_from_memory(text.data, false);
+        } else {
+            text_data = Data.create();
+        }
+        Context context = Context.create();
+        context.op_verify(sig_data, text_data);
+        VerifyResult* verify_res = context.op_verify_result();
+        if (verify_res == null || verify_res.signatures == null) return null;
+        return verify_res.signatures.fpr;
+    } finally {
+        global_mutex.unlock();
+    }
+}
+
+public static Gee.List<Key> get_keylist(string? pattern = null, bool secret_only = false) throws GLib.Error {
+    global_mutex.lock();
+    try {
+        initialize();
+
+        Gee.List<Key> keys = new ArrayList<Key>();
+        Context context = Context.create();
+        context.op_keylist_start(pattern, secret_only ? 1 : 0);
+        try {
+            while (true) {
+                Key key = context.op_keylist_next();
+                keys.add(key);
+            }
+        } catch (Error e) {
+            if (e.code != GPGError.ErrorCode.EOF) throw e;
+        }
+        context.op_keylist_end();
+        return keys;
+    } finally {
+        global_mutex.unlock();
+    }
+}
+
+public static Key? get_public_key(string sig) throws GLib.Error {
+    return get_key(sig, false);
+}
+
+public static Key? get_private_key(string sig) throws GLib.Error {
+    return get_key(sig, true);
+}
+
+private static Key? get_key(string sig, bool priv) throws GLib.Error {
+    global_mutex.lock();
+    try {
+        initialize();
+        Context context = Context.create();
+        Key key = context.get_key(sig, priv);
+        return key;
+    } finally {
+        global_mutex.unlock();
+    }
+}
+
+private static string get_string_from_data(Data data) {
+    const size_t BUF_SIZE = 256;
+    data.seek(0);
+    uint8[] buf = new uint8[BUF_SIZE + 1];
+    ssize_t len = 0;
+    string res = "";
+    do {
+        len = data.read(buf, BUF_SIZE);
+        if (len > 0) {
+            buf[len] = 0;
+            res += (string) buf;
+        }
+    } while (len > 0);
+    return res;
+}
+
+private static uint8[] get_uint8_from_data(Data data) {
+    const size_t BUF_SIZE = 256;
+    data.seek(0);
+    uint8[] buf = new uint8[BUF_SIZE + 1];
+    ssize_t len = 0;
+    ByteArray res = new ByteArray();
+    do {
+        len = data.read(buf, BUF_SIZE);
+        if (len > 0) {
+            res.append(buf[0:len]);
+        }
+    } while (len > 0);
+    return res.data;
+}
+
+private static void initialize() {
+    if (!initialized) {
+        check_version();
+        initialized = true;
+    }
+}
+
+}