xmpp-vala/src/module/xep/0203_delayed_delivery.vala


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

using Xmpp.Core;

namespace Xmpp.Xep.DelayedDelivery {
    private const string NS_URI = "urn:xmpp:delay";

    public class Module : XmppStreamModule {
        public static ModuleIdentity<Module> IDENTITY = new ModuleIdentity<Module>(NS_URI, "0203_delayed_delivery");

        public static void set_message_delay(Message.Stanza message, DateTime datetime) {
            StanzaNode delay_node = (new StanzaNode.build("delay", NS_URI)).add_self_xmlns();
            delay_node.put_attribute("stamp", DateTimeProfiles.to_datetime(datetime));
            message.stanza.put_node(delay_node);
        }

        public static DateTime? get_time_for_message(Message.Stanza message) {
            StanzaNode? delay_node = message.stanza.get_subnode("delay", NS_URI);
            if (delay_node != null) {
                return get_time_for_node(delay_node);
            }
            return null;
        }

        public static DateTime? get_time_for_node(StanzaNode node) {
            string? time = node.get_attribute("stamp");
            if (time != null) return DateTimeProfiles.parse_string(time);
            return null;
        }

        public override void attach(XmppStream stream) {
            stream.get_module(Message.Module.IDENTITY).received_pipeline.connect(new ReceivedPipelineListener());
        }

        public override void detach(XmppStream stream) { }

        public override string get_ns() { return NS_URI; }
        public override string get_id() { return IDENTITY.id; }
    }

public class ReceivedPipelineListener : StanzaListener<Message.Stanza> {

    private const string[] after_actions_const = {};

    public override string action_group { get { return "ADD_NODE"; } }
    public override string[] after_actions { get { return after_actions_const; } }

    public override async void run(Core.XmppStream stream, Message.Stanza message) {
        DateTime? datetime = Module.get_time_for_message(message);
        if (datetime != null) message.add_flag(new MessageFlag(datetime));
    }
}

    public class MessageFlag : Message.MessageFlag {
        public const string ID = "delayed_delivery";

        public DateTime datetime { get; private set; }

        public MessageFlag(DateTime datetime) {
            this.datetime = datetime;
        }

        public static MessageFlag? get_flag(Message.Stanza message) { return (MessageFlag) message.get_flag(NS_URI, ID); }

        public override string get_ns() { return NS_URI; }
        public override string get_id() { return ID; }
    }
}